package Cpanel::CPAN::Algorithm::Dependency::Source::File;

=pod

=head1 NAME

Cpanel::CPAN::Algorithm::Dependency::Source::File - File source for dependency heirachys

=head1 DESCRIPTION

Cpanel::CPAN::Algorithm::Dependency::Source::File implements a
L<source|Cpanel::CPAN::Algorithm::Dependency::Source> where the items are stored in a flat
file or a relatively simple format.

=head2 File Format

The file should be an ordinary text file, consisting of a series of lines,
with each line completely containing the information for a single item.
Blank lines, or lines beginning with the hash character '#' will be
ignored as comments.

For a single item line, only word characters will be used. A 'word character'
consists of all letters and numbers, and the underscore '_' character.
Anything that is not a word character will be assumed to be a separator.

The first word will be used as the name or id of the item, and any further
words in the line will be used as other items that this one depends on. For
example, all of the following are legal.

  # A single item with no dependencies
  Foo

  # Another item that depends on the first one
  Bar Foo

  # Depending on multiple others
  Bin Foo Bar

  # We can use different separators
  One:Two|Three-Four+Five=Six Seven

  # We can also use multiple non-word characters as separators
  This&*&^*&File:  is& & & :::REALLY()Neat

From the examples above, it should be easy to create your own files.

=head1 METHODS

This documents the methods differing from the ordinary
L<Cpanel::CPAN::Algorithm::Dependency::Source> methods.

=cut

use strict;
use base 'Cpanel::CPAN::Algorithm::Dependency::Source';

use vars qw{$VERSION};

BEGIN {
    $VERSION = '1.102';
}

#####################################################################
# Constructor

=pod

=head2 new $filename

When constructing a new Cpanel::CPAN::Algorithm::Dependency::Source::File object, an
argument should be provided of the name of the file to use. The constructor
will check that the file exists, and is readable, returning C<undef>
otherwise.

=cut

sub new {
    my $class = shift;
    my $filename = shift or return undef;
    return undef unless -r $filename;

    # Get the basic source object
    my $self = $class->SUPER::new or return undef;

    # Add our arguments
    $self->{filename} = $filename;

    $self;
}

#####################################################################
# Private Methods

sub _load_item_list {
    my $self = shift;

    # Load the contents of the file
    local $/ = undef;
    open( FILE, $self->{filename} ) or return undef;
    defined( my $source = <FILE> ) or return undef;
    close(FILE) or return undef;

    # Split, trim, clean and remove comments
    my @content = grep { !/^\s*(?:\#|$)/ }
      split /\s*[\015\012][\s\015\012]*/, $source;

    # Parse and build the item list
    my @Items = ();
    foreach my $line (@content) {

        # Split the line by non-word characters
        my @sections = grep { length $_ } split /\W+/, $line;
        return undef unless scalar @sections;

        # Create the new item
        my $Item = Cpanel::CPAN::Algorithm::Dependency::Item->new(@sections) or return undef;
        push @Items, $Item;
    }

    \@Items;
}

1;

=pod

=head1 SUPPORT

To file a bug against this module, use the CPAN bug tracking system

L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Algorithm-Dependency>

For other comments, contact the author.

=head1 AUTHOR

Adam Kennedy, L<http://ali.as/>, cpan@ali.as

=head1 SEE ALSO

L<Cpanel::CPAN::Algorithm::Dependency>

=head1 COPYRIGHT

Copyright (c) 2003 - 2005 Adam Kennedy. All rights reserved.

This program is free software; you can redistribute
it and/or modify it under the same terms as Perl itself.

The full text of the license can be found in the
LICENSE file included with this module.

=cut
